Laboratorio de código SAS. Ordenaciones con HASH vs. PROC SORT

* DATASET DE PRUEBA PARA COMPARACION DE TIEMPOS;
data uno;
    array v(10);
    do i = 1 to 1000000;
        importe = ranuni(mod(time(), 1) * 1000) * 10000;
        do j = 1 to 5;
            v(j) = ranuni(34) * 100;
        end;
        output;
    end;
    drop i j;
run;

* MACRO QUE AÑADE RESULTADOS AL DATASET DE TEST;
%macro aniade(descripcion);
    data borra;
        ejecucion = &i.;
        metodo = "&descripcion.";
        tiempo = time() - &inicio.;
        output;
    run;
    data test;
        set test borra;
    run;
    proc delete data=borra; 
    run;
%mend;

* MACRO QUE LANZA LA PRUEBA COMPARATIVA;
%macro test(ejecuciones);
    %do i = 1 %to &ejecuciones.;
        %let inicio = %sysfunc(time());
        
        * MÉTODO 1: PROC SORT;
        proc sort data=uno out=dos;
            by importe;
        run;
        
        %if &i. = 1 %then %do;
            data test;
                ejecucion = &i.;
                length metodo $20.;
                metodo = "PROC SORT";
                tiempo = time() - &inicio.;
                output;
            run;
        %end;
        %else %do;
            %aniade(PROC SORT);
        %end;

        %let inicio = %sysfunc(time());
        
        * MÉTODO 2: OBJETOS HASH;
        data _null_;
            if 0 then set uno;
            declare hash obj (dataset: 'uno', hashexp: 20, ordered: 'a');
            obj.defineKey('importe');
            obj.defineData(all: 'YES');
            obj.defineDone();
            obj.output(dataset: 'dos_hash');
            stop;
        run;

        %aniade(HASH);
    %end;
%mend;

* LANZAMOS 10 EJECUCIONES;
%test(10);

* ORDENAMOS POR TIEMPO PARA VER RESULTADOS;
proc sort data=test; 
    by tiempo; 
run;

proc print data=test;
run;